Setelah membuka-buka file yang ada di komputer saya, saya menemukan file notepad yang berisikan scrip trik flash. Sebenarnya trik ini dikasi oleh teman saya kurang lebih 2 tahun yang lalu. Trik ini sebenarnya diperoleh dari internet (saya lupa alamatnya). Trik ini berisikan dengan trik untuk membuat efek partikel (mungkin mirib🙂 ) ya secara singkat, animasinya terdiri dari bola-bola yang berputar-putar membentuk suatu pola yang mirib dengan particel (dalam ilmu kimia).

Ingin melihat bagaimana animasi dan cara pembuatannya??? silahakan lanjut baca artikel berikut ini….

 

Penyelesaiannya adalah sebagai berikut.

  • Buka program flash, dan pada frame 1 buatlah satu buah objek (misal lingkaran), rubah objek lingkaran tsb menjadi movie klip.

  • Atur ukuran movie lingkaran menjadi kecil (supaya gerakannya lebih dinamis)
  • Silahkan delete objek tsb untuk menghilangkannya dari stage atau area kerja, sekarang beralih ke library, klik kanan objek lingkaran dan pilih linkage
  • Maka akan muncul kotak dialog seperti gambar berikut. Pada identifier beri nama “particle” dam centang export for action scrip > OK.

  • Kalau sudah sekarang kita beralih ke frame 1, tekan F9 untuk memasuki jendela action, dan masukan scrip sebagai berikut.
var numParticles:Number = 15;
var minDist:Number = 150;
var springAmount:Number = .001;

init();
function init():Void
{
 for(var i:Number=0;i<numParticles;i++)
 {
 var particle:MovieClip = attachMovie("particle", "p" + i, i);
 particle._x = Math.random() * Stage.width;
 particle._y = Math.random() * Stage.height;
 particle.vx = Math.random() * 6 - 4;
 particle.vy = Math.random() * 6 - 4;
 }
}

function onEnterFrame():Void
{
 for(var i:Number = 0;i<numParticles;i++)
 {
 var particle:MovieClip = this["p" + i];
 particle._x += particle.vx;
 particle._y += particle.vy;
 if(particle._x > Stage.width)
 {
 particle._x = 0;
 }
 else if(particle._x < 0)
 {
 particle._x = Stage.width;
 }
 if(particle._y > Stage.height)
 {
 particle._y = 0;
 }
 else if(particle._y < 0)
 {
 particle._y = Stage.height;
 }
 }

 clear();
 for(i=0;i<numParticles-1;i++)
 {
 var partA:MovieClip = this["p" + i];
 for(var j:Number = i+1;j<numParticles;j++)
 {
 var partB:MovieClip = this["p" + j];
 spring(partA, partB);
 }
 }
}

function spring(partA:MovieClip, partB:MovieClip):Void
{
 var dx:Number = partB._x - partA._x;
 var dy:Number = partB._y - partA._y;
 var dist:Number = Math.sqrt(dx*dx + dy*dy);
 if(dist < minDist)
 {
 lineStyle(1, 0xff0000, 100 - dist / minDist * 100);
 moveTo(partA._x, partA._y);
 lineTo(partB._x, partB._y);
 var ax:Number = dx * springAmount;
 var ay:Number = dy * springAmount;
 partA.vx += ax;
 partA.vy += ay;
 partB.vx -= ax;
 partB.vy -= ay;
 }
}

  • rubah kecepatan frame (frame rate) menjadi 20 atau lebih tinggi lagi.
  • Tekan ctrl + Enter untuk menjalankan animasi, semoga bisa berjalan🙂